HULLSTRN program

10 PRINT "Submarine Hull Strength Program"
15 PRINT "(for cylindrical steel hulls, elastic buckling only)"
20 PRINT "Enter hull thickness in inches: ";
30 INPUT T
40 PRINT "Enter hull radius in inches: ";
50 INPUT R
60 PRINT "Enter hull length in inches (between reinforcing bands): ";
70 INPUT L
80 PRINT "Enter Poisson's Ratio (.3 for steel): ";
90 INPUT V
100 PRINT "Enter axial modulus of elasticity (3E7 for steel): ";
110 INPUT E
190 LET X=(T/R)*(T/R)
200 LET Y=V*V
210 LET Z=1/(1-Y)
220 LET W=Z*X
230 LET Q=W^.25
240 LET P=.807*((E*T*T)/(L*R))
250 LET P=P*Q
260 PRINT
270 PRINT "According to Roark, FORMULAS FOR STRESS AND STRAIN, 1961"
280 PRINT "Crush pressure           = ", INT(P);" PSI"
290 LET D=P*2.245
310 PRINT "Crush depth in sea water = ", INT(D);" feet."
320 PRINT
330 PRINT "According to Flugge, HANDBOOK OF ENGINEERING MECHANICS, 1962"
340 LET Z=(L*L*((1-(V*V))^.5))/(R*T)
350 LET Z1=1.04*(Z^.5)
360 LET K=(E*(T*T*T))/(12*(1-(V*V)))
370 LET P=(Z1*3.14159*3.14159*K)/(L*L*R)
380 PRINT "Crush pressure            = ", INT(P);" PSI"
390 LET D=P*2.245
400 PRINT "Crush depth in sea water  = ", INT(D);" feet."
410 END